(*
 * LANGUAGE    : ANS Forth
 * PROJECT     : Forth Environments
 * DESCRIPTION : Mandelbrot set for non-critical orbit
 * CATEGORY    : Graphic example
 * AUTHOR      : Marcel Hendrix 
 * LAST CHANGE : Thursday, January 01, 2004 8:13 PM, Marcel Hendrix 
 *)



        NEEDS -miscutil
	NEEDS -graphics

        REVISION -manvar "ÄÄÄ Mandelbrot, orbits  Version 1.00 ÄÄÄ"

	PRIVATES


DOC
(*
 Mandelbrot set for non-critical orbit.
*)
ENDDOC

-- Parameters 
      -0.2e FVALUE Aa
	 0e FVALUE Bb
       1.8e FVALUE delH
       1.5e FVALUE delV
         9   VALUE amp

-- Globals
       0. DVALUE @XY    PRIVATE

: COLORIZE ( ix -- ) 
		3 * palette + 
		C@+ amp * >S
		C@+ amp * >< S> OR >S
		C@  amp * #16 LSHIFT S> OR >S
		@XY S> SET-MDOT ;

: INNERLOOP ( x y -- ) 
		2DUP TO @XY UNSCALE? DROP FLOCALS| yy xx |
		xx Aa F+ FLOCAL a1
		yy Bb F+ FLOCAL b1
		0e TO xx  0.6e TO yy
		 #50 1 DO  
		 	   xx  xx FSQR yy FSQR F- a1 F+ TO xx
			       F2* yy F* 	  b1 F+ TO yy
			   xx FSQR yy FSQR F+ 100e F> IF  I COLORIZE LEAVE  ENDIF
		     LOOP ;P

: COMPUTE	TEXTMODE? DUP >R IF GRAPHICS ENDIF  
		0 0 Xmax Ymax  delH FNEGATE delV FNEGATE delH delV SET-GWINDOW GCLEAR 
		#50 RANDOMPALETTE
		RESET-MDOTS
		  Xmax 0 ?DO  Ymax 0 ?DO  J I INNERLOOP  LOOP  LOOP
		FLUSH-MDOTS
		R> IF  TEXT  ENDIF ;

:ABOUT		CR ." Type COMPUTE for a Mandelbot fractal."
		CR
		CR ."  1.4e TO delH  1.4e TO delV -- zoom picture "
		CR ."  9 TO amp  COMPUTE          -- influence contrast " 
		CR
		CR ." -1.754878e TO Aa  0e        TO Bb COMPUTE "
		CR ." -1.543689e TO Aa  0e        TO Bb COMPUTE " 
		CR ." 5e 4e F/   TO Aa  0e        TO Bb COMPUTE " 
		CR ." -1e        TO Aa  0e        TO Bb COMPUTE " 
		CR ." -0.75e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.3e      TO Aa  0e        TO Bb COMPUTE "
		CR ." -0.122561e TO Aa  0.744862e TO Bb COMPUTE "
		CR ." -0.101096e TO Aa  0.956287e TO Bb COMPUTE "
		CR ."  0.11e     TO Aa  0.67e     TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0.25e     TO Bb COMPUTE "
		CR ." -0.318472e TO Aa  0.041257e TO Bb COMPUTE " ;

                .ABOUT -manvar CR
		DEPRIVE

                              (* End of Source *)